# Maintainer: Juanjo Gutiérrez <juanjo at gutierrezdequevedo dot com>
pkgname=gvisor-tap-vsock
pkgver=0.7.0
pkgrel=1
pkgdesc="A new network stack based on gVisor"
arch=(x86_64)
url="https://github.com/containers/gvisor-tap-vsock"
license=(Apache)
depends=(glibc)
makedepends=(go)
source=($url/archive/v$pkgver/$pkgname-$pkgver.tar.gz)
sha256sums=('e526b8bf568a5145f4f265a8d450483be27c82717e60f4f22902589a78f68e1f')

prepare(){
  cd $pkgname-$pkgver
  mkdir -p build/
}


build() {
  cd $pkgname-$pkgver
  export CGO_CPPFLAGS="${CPPFLAGS}"
  export CGO_CFLAGS="${CFLAGS}"
  export CGO_CXXFLAGS="${CXXFLAGS}"
  export CGO_LDFLAGS="${LDFLAGS}"
  export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
  go build -o build ./cmd/...
}

package() {
  cd $pkgname-$pkgver
  install -Dm 0755 "build/vm" "$pkgdir/usr/bin/gvforwarder"
  install -Dm 0755 "build/qemu-wrapper" "$pkgdir/usr/bin/qemu-wrapper"
  install -Dm 0755 "build/gvproxy" "$pkgdir/usr/lib/podman/gvproxy"
}