# Maintainer: Alexander F. Rødseth <xyproto@archlinux.org>
# Contributor: John <graysky@archlinux.us>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Judd Vinet <jvinet@zeroflux.org>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>

pkgname=distcc
pkgver=3.4
pkgrel=7
_gccver=13.1.1 # Current GCC version, used for symlinks. See FS#69044
pkgdesc='Distributed compilation service for C, C++ and Objective-C'
arch=(x86_64)
url='https://github.com/distcc/distcc'
license=(GPL)
depends=(avahi popt python 'gcc=13.1.1')
makedepends=(git gtk3)
optdepends=("gcc=$_gccver"
            'gtk3: for distccmon')
backup=(etc/conf.d/distccd
        etc/distcc/hosts)
source=("git+$url?signed#tag=v$pkgver"
        distccd.conf.d
        distccd.service
        sysusers.conf
        native-compiler-triple.patch)
b2sums=('SKIP'
        'c342704d4f0b1f649a14ef71645caf24eb100384e03d574116efe7360e85b1ba98ff7b6fb8f5144b0a94d5ddb568f0ef262ddde053e678044e555c8981cf73aa'
        '02bf0f4d9baef948087af7719886e4f31c3002a52192abe0b089ff3fbc0b081a8b7afafbe7d48fa3e3b75cc949360b12f0013a727283ca8b4bfedbbfc9c72233'
        'abbd289f57bf0b68c47607cdf024b87033d9e5bd9e13838c5e949677d9ebbffcb9a62a083a305ac3155285c92ca83a76e47da84a11d9844f77638e6abdd9f47c'
        '5e5970a840428afea1da0c25451fdd199eba5d690110cec749e73fccc0d70b8500022a685d5d5dc6369ffcfac6a28b9dedb2cf0d33e9aec58f85c4072fc3c5b0')
validpgpkeys=(30782E2BE4EB9FD5B293D3DA6D100BF096B8A005) # Shawn Landden

prepare() {
  patch --directory=$pkgname --forward --strip=1 --input="${srcdir}/native-compiler-triple.patch"
  cd $pkgname
  ./autogen.sh
  sed -i 's/ install-gnome-data//g' Makefile.in
}

build() {
  cd $pkgname

  # ref: https://github.com/distcc/distcc/issues/454#issuecomment-1087865811
  export CFLAGS+=' -DPY_SSIZE_T_CLEAN -fcommon'

  # ref: https://bugs.archlinux.org/task/78400
  export NATIVE_COMPILER_TRIPLE=x86_64-pc-linux-gnu-gcc

  ./configure \
    --enable-rfc2553 \
    --mandir=/usr/share/man \
    --prefix=/usr \
    --sbindir=/usr/bin \
    --sysconfdir=/etc \
    --with-gtk

  make WERROR_CFLAGS= INCLUDESERVER_PYTHON=/usr/bin/python
}

package() {
  make -C $pkgname \
    DESTDIR="$pkgdir" \
    INCLUDESERVER_PYTHON=/usr/bin/python \
    install

  install -Dm644 distccd.conf.d "$pkgdir/etc/conf.d/distccd"
  install -Dm644 distccd.service \
    "$pkgdir/usr/lib/systemd/system/distccd.service"

  # Package symlinks
  _targets=(c++ c89 c99 cc clang clang++ cpp g++ gcc $CARCH-pc-linux-gnu-g++
            $CARCH-pc-linux-gnu-gcc $CARCH-pc-linux-gnu-gcc-$_gccver)
  install -d "$pkgdir/usr/lib/$pkgname/bin"
  for bin in "${_targets[@]}"; do
    # For whitelist since version 3.3, see FS#57978
    ln -sf ../../bin/$pkgname "$pkgdir/usr/lib/$pkgname/$bin"
    # Needed for makepkg to work
    ln -sf ../../../bin/$pkgname "$pkgdir/usr/lib/$pkgname/bin/$bin"
  done

  # FS#67629
  install -Dm644 sysusers.conf "$pkgdir/usr/lib/sysusers.d/distccd.conf"
}