# Maintainer: Anatol Pomozov
# Contributor: Tommaso Sardelli <lacapannadelloziotom at gmail dot com>

pkgname=bpftrace
pkgver=0.16.0
pkgrel=3
pkgdesc='High-level tracing language for Linux eBPF'
arch=('x86_64')
url='https://github.com/iovisor/bpftrace'
license=('Apache')
depends=('libelf' 'zlib' 'llvm-libs' 'clang' 'bcc' 'libbpf')
makedepends=('cmake' 'llvm' 'git' 'linux-headers' 'ninja' 'gtest' 'cereal'
             'asciidoctor' 'xxd')
options=(!strip)
source=(
"https://github.com/iovisor/bpftrace/archive/v$pkgver/bpftrace-$pkgver.tar.gz"
"https://github.com/iovisor/bpftrace/commit/89188defce9f323fab39a2aec438be93ad6c0376.patch"
)
sha512sums=('52ca4fea4e2f8d2cbf0f9f1bc69af0ee3408201f019006dd2e838b9458cfc01761eba3df24c39e05cf93220d85d0cecc69bb44ec72f9f44cec0eb94479bff734'
            '2d4e64803c7abc98a7d7557deb25e63e0c8505d49ad4c019840dd8b90e1886c2a06704e6782a62ba31b4e0ffee57c38992f22f46e10161eb5b8570fe47e6a677')
prepare(){
  cd bpftrace-$pkgver
  patch -Np1 -i ../89188defce9f323fab39a2aec438be93ad6c0376.patch
}
build() {
  cd bpftrace-$pkgver

  cmake -DCMAKE_BUILD_TYPE=Release -DCMAKE_INSTALL_PREFIX=/usr -G Ninja -B build
  ninja -C build
}

package() {
  cd bpftrace-$pkgver
  DESTDIR="$pkgdir" ninja -C build install
}