# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>

pkgname=upower
pkgver=1.90.0
pkgrel=1.1
pkgdesc="Abstraction for enumerating power devices, listening to device events and querying history and statistics"
url="https://upower.freedesktop.org"
arch=(x86_64)
license=(GPL)
depends=(systemd libimobiledevice libgudev)
makedepends=(docbook-xsl gobject-introspection python git gtk-doc meson)
checkdepends=(python-{dbus,dbusmock,gobject} umockdev)
backup=(etc/UPower/UPower.conf)
options=(debug)
_commit=d4259c009b3ca1169dfd19231a040c233fc3b58d  # tags/v1.90.0^0
source=("git+https://gitlab.freedesktop.org/upower/upower.git#commit=$_commit"
       "up-device-supply-battery.patch")
sha256sums=('SKIP'
            'SKIP')

pkgver() {
  cd upower
  git describe --tags | sed -e 's/^v\|^UPOWER_//;s/_/\./g;s/[^-]*-g/r&/;s/-/+/g'
}

prepare() {
  cd upower
  patch -p1 -i ${srcdir}/up-device-supply-battery.patch
}

build() {
  arch-meson upower build
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  depends+=(libg{lib,object,io}-2.0.so)
  provides+=(libupower-glib.so)

  meson install -C build --destdir "$pkgdir"
}