# Maintainer: Alexander F. Rødseth <xyproto@archlinux.org>
# Contributor: loqs <bugs-archlinux@entropy-collector.net>
# Contributor: Gabriel Souza Franco <gabrielfrancosouza@gmail.com>
# Contributor: Florian Pritz
# Contributor: Jonas Heinrich <onny@project-insanity.org>
# Contributor: Jordi De Groof <jordi.degroof@gmail.com>
# Contributor: mickele
# Contributor: manwithgrenade
# Contributor: bricem13
# Contributor: gborzi

pkgname=freecad
pkgver=0.20
pkgrel=1
pkgdesc='Feature based parametric 3D CAD modeler'
arch=(x86_64)
url='https://freecad.org/'
license=(LGPL)
depends=(boost-libs glew jsoncpp libspnav med netcdf opencascade openmpi pyside2 pyside2-tools
         python-matplotlib coin python-pivy python-ply pugixml qt5-svg qt5-tools qt5-webengine
         qt5-webchannel qt5-x11extras qt5-xmlpatterns xerces-c)
makedepends=(boost cmake fmt eigen git ninja python-shiboken2 shiboken2 swig utf8cpp)
optdepends=(
'openscad: OpenSCAD support'
'graphviz: dependency graph support'
'python-markdown: markdown support in addon manager'
'python-gitpython: support downloading addons with git'
)
source=("https://github.com/$pkgname/$pkgname-Bundle/releases/download/$pkgver/freecad_source.tar.gz")
b2sums=('d2db9f0d6585492663e3527ca058b8caa1c6a7f7b5258a53c35c22ae6f854d2ce703202fb666d11d43872b9ffff3b46a0b600449c4ca6d8733df42e2e38d4bff')

# prepare() {
#
# }

build() {
  cmake \
    -B build \
    -D BUILD_ENABLE_CXX_STD=C++17 \
    -D BUILD_FLAT_MESH=ON \
    -D CMAKE_BUILD_TYPE=Release \
    -D CMAKE_C_FLAGS="$CFLAGS -fPIC -w" \
    -D CMAKE_CXX_FLAGS="$CXXFLAGS -fPIC -w" \
    -D CMAKE_INSTALL_DATADIR=/usr/share/freecad \
    -D CMAKE_INSTALL_DATAROOTDIR=/usr/share \
    -D CMAKE_INSTALL_DOCDIR=/usr/share/freecad/doc \
    -D CMAKE_INSTALL_BINDIR=/usr/lib/freecad/bin \
    -D CMAKE_INSTALL_LIBDIR=/usr/lib/freecad/lib \
    -D CMAKE_INSTALL_PREFIX=/usr/lib/freecad \
    -D FREECAD_USE_EXTERNAL_PIVY=ON \
    -D FREECAD_USE_QT_FILEDIALOG=ON \
    -D PYTHON_EXECUTABLE=/usr/bin/python \
    -D INSTALL_TO_SITEPACKAGES=ON \
    -G Ninja \
    -S .
  ninja -C build
}

package() {
  DESTDIR="$pkgdir" ninja -C build install

  # Thumbnailer
  install -Dm755 src/Tools/$pkgname-thumbnailer -t "$pkgdir/usr/bin/"

  # Symlinks in /usr/bin
  install -d "$pkgdir/usr/bin"
  ln -sf /usr/lib/freecad/bin/FreeCAD "$pkgdir/usr/bin/freecad"
  ln -sf /usr/lib/freecad/bin/FreeCAD "$pkgdir/usr/bin/FreeCAD"
  ln -sf /usr/lib/freecad/bin/FreeCADCmd "$pkgdir/usr/bin/freecadcmd"
  ln -sf /usr/lib/freecad/bin/FreeCADCmd "$pkgdir/usr/bin/FreeCADCmd"
}