# $Id: PKGBUILD,v 1.27 2007/03/13 17:48:30 jgc Exp $
# Maintainer: tobias <tobias@archlinux.org>
# Original Contributor: Tom Newsom <Jeepster@gmx.co.uk>
# New Version - Contributor: Bob Finch <w9ya@arrl.net>
# with help from J. Santiago Hirschfeld <jsantiagoh@yahoo.com.ar> aka Angelus

pkgname=wxgtk
pkgver=2.8.4.0
force=y
pkgrel=3
pkgdesc="wxGTK - GTK+ implementation of wxWidgets API for GUI"
arch=(i686 x86_64)
license=('LGPL')
depends=('gtk2>=2.10.9' 'mesa')
source=(http://switch.dl.sourceforge.net/sourceforge/wxwindows/wxGTK-2.8.4.tar.bz2)
url="http://wxwidgets.org"
md5sums=('22e42c1601d9759530c875ffa2c3c554')
sha1sums=('75e9e124de59f5431fcaccd24981ee4781ee9a38')

build() {
  cd ${startdir}/src/wxGTK-2.8.4
  autoconf
  ./configure --prefix=/usr --with-gtk=2 --with-opengl --enable-unicode \
	  --without-gnomeprint --disable-optimize || return 1
  make || return 1
  make -C locale allmo
  make DESTDIR=${startdir}/pkg install || return 1
  cd contrib/src
  make || return 1
  make DESTDIR=${startdir}/pkg install || return 1
}