# Contributor: Christian Cornelssen <email@address.invalid>
# Contributor: Geoffroy Carrier <geoffroy.carrier@koon.fr>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
# Maintainer: schuay <jakob.gruber@gmail.com>

pkgname=puzzles
pkgver=20211030
pkgrel=1
pkgdesc="Simon Tatham's Portable Puzzle Collection"
arch=('x86_64')
url="https://www.chiark.greenend.org.uk/~sgtatham/puzzles/"
license=('MIT')
makedepends=('pkgconfig' 'git' 'cmake' 'perl' 'imagemagick')
_gtkver=2
depends=("gtk$_gtkver")
source=("git+https://git.tartarus.org/simon/puzzles.git#commit=640f9235c79cdb1a924b0148cb312b0f02253364")
md5sums=('SKIP')

prepare() {
    cd ${pkgname}

    # Tweak desktop file generation to use proper icon paths.
    sed -i 's,Icon=\${binary_name}-48d24,Icon=${binary_name},' \
            puzzle.desktop.in
    sed -i -e 's,share/pixmaps,share/icons/hicolor/48x48/apps,' \
           -e 's,\${binary_name}-48d24\.png,${binary_name}.png,' \
            cmake/platforms/unix.cmake
}

build() {
    cd ${pkgname}
    cmake -B build -S . \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_BUILD_TYPE=Release \
        -DPUZZLES_GTK_VERSION="$_gtkver" \
        -DNAME_PREFIX=puzzles-
    cmake --build build
}

package() {
    cd ${pkgname}
    DESTDIR="$pkgdir" cmake --build build --target install
    install -Dm644 -t "${pkgdir}"/usr/share/licenses/${pkgname} LICENCE
}