# Maintainer: Jingbei Li <i@jingbei.li>
# Contributer: David McInnis <dave@dave3.xyz>
# Contributer: Fabien Dubosson <fabien.dubosson@gmail.com>

pkgname=python-keras
_pkgname="keras"
pkgver=2.6.0
pkgrel=1
pkgdesc="Deep Learning library (convnets, recurrent neural networks, and more)"
arch=('any')
url="https://github.com/keras-team/keras"
license=('Apache')
depends=(
  absl-py
  python-h5py
  python-keras-preprocessing
  python-numpy
  python-pandas
  python-pydot
  python-scipy
  python-six
  python-yaml
  python-pillow
  python-tensorflow
)
makedepends=(bazel python-pip python-setuptools python-wheel)
source=("https://github.com/keras-team/keras/archive/v$pkgver/keras-v$pkgver.tar.gz")
sha256sums=('15586a3f3e1ed9182e6e0d4c0dbd052dfb7250e779ceb7e24f8839db5c63fcae')

build() {
  cd "$srcdir/${_pkgname}-${pkgver}"
  bazel build //keras/tools/pip_package:build_pip_package
  bazel-bin/keras/tools/pip_package/build_pip_package "${srcdir}"/tmp
}

package_python-keras() {
  cd "$srcdir/${_pkgname}-${pkgver}"
  WHEEL_PACKAGE=$(find "${srcdir}"/tmp -name "keras*.whl")
  pip install --ignore-installed --upgrade --root "${pkgdir}"/ $WHEEL_PACKAGE --no-dependencies
  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"
}