# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Ebubekir KARUL <ebubekirkarul@yandex.com>
# Contributor: s1gma,shirokuro

pkgbase=scapy
pkgname=('scapy' 'python-scapy')
pkgver=2.4.4
pkgrel=0
pkgdesc='Powerful interactive packet manipulation program written in Python'
url='http://www.secdev.org/projects/scapy/'
arch=('any')
license=('GPL2')
makedepends=('tcpdump' 'python-setuptools')
checkdepends=('python-cryptography' 'python-pyx' 'python-matplotlib'
              'graphviz' 'sox')
source=(https://github.com/secdev/scapy/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz
        # Until scapy 2.4.5
        https://patch-diff.githubusercontent.com/raw/secdev/scapy/pull/3000.patch
)
sha256sums=('abe1b7fa606350df90209a60d23df727705097453b3dcb626bf36b3539d44021'
            '36d526e9904f34d2d79e0e451bb55252e36823b081e416488bdb285f4ddcb76e')
sha512sums=('d6078901839157b3f3d63c304f43f88a41b9bd2fb32cc917624c12fe822818d02256d6661b5076689c0f59c51e4ab35195ddf555f0d1f6df95faac1c646ee8c6'
            '9ce1de2c5fd16c437135f0ca024851a23f310560188ad047f03a66a6e7c2e3dae54f820c9714bf1a3fc6bc5e84991aaa053768fac01205c2a0208662a1e456ee')

prepare() {
  cd ${pkgbase}-${pkgver}
  echo -n "$pkgver" >scapy/VERSION

  # Until scapy 2.4.5 is released, fix "liblibc.a" exception
  # https://github.com/secdev/scapy/issues/3100
  patch --forward --strip=1 --fuzz=3 --input="${srcdir}/3000.patch"
}

build() {
  cd ${pkgbase}-${pkgver}
  python setup.py build
}

check() {
  # Run only main tests, without network access
  cd ${pkgbase}-${pkgver}/test
  ./run_tests -K netaccess -F
}

package_scapy() {
  depends=('python' 'python-scapy')
  optdepends=('ipython: enhanced shell with autocompletion and history')
  pkgdesc+=' (tools)'
  cd ${pkgbase}-${pkgver}
  python setup.py install -O1 --skip-build --root="${pkgdir}" --prefix=/usr
  install -d "${pkgdir}/usr/share/doc"
  ln -sf /usr/share/doc/python-scapy "${pkgdir}/usr/share/doc/${pkgname}"
  rm -r "${pkgdir}/usr/lib"
}

package_python-scapy() {
  pkgdesc+=' (library)'
  depends=('tcpdump' 'python')
  optdepends=('python-cryptography: WEP, IPsec and SSL/TLS support'
              'python-pyx: psdump() and pdfdump() functions'
              'python-matplotlib: plotting support'
              'graphviz: conversations() method support'
              'sox: for VOIP support')
  cd ${pkgbase}-${pkgver}
  python setup.py install -O1 --skip-build --root="${pkgdir}" --prefix=/usr
  install -Dm 644 doc/scapy/*.rst -t "${pkgdir}/usr/share/doc/${pkgname}"
  rm -r "${pkgdir}"{/usr/bin,/usr/share/man}
}

# vim: ts=2 sw=2 et: