# Maintainer: David Runge <dvzrv@archlinux.org>
# Contributor: Ray Rashif <schiv@archlinux.org>
# Contributor: damir <damir@archlinux.org>
# Contributor: Lukas Sabota <punkrockguy318@comcast.net>
# Contributor: Brice Carpentier <brice@dlfp.org>

pkgname=scons
pkgver=4.1.0
pkgrel=1
pkgdesc="Extensible Python-based build utility"
arch=('any')
url="https://scons.org"
license=('MIT')
depends=('python')
makedepends=('python-sphinx' 'python-sphinx_rtd_theme' 'fop' 'docbook2x' 
             'texlive-bin' 'graphviz' 'ghostscript' 'lynx' 'python-lxml' 
             'python-setuptools' 'texlive-latexextra' 'python-wheel'
             'python-importlib-metadata' 'python-rst2pdf')
# potential additions include ipkg, rpm
checkdepends=('clang' 'gdc' 'dmd' 'ldc' 'lib32-glibc' 'nasm' 'python-pytest'
              'python-virtualenv' 'rpm-tools' 'swig' 'zip')
source=("$pkgname-$pkgver.tar.gz::https://github.com/${pkgname}/${pkgname}/archive/${pkgver}.tar.gz"
         scons-manpage-packaging-fix.patch::https://github.com/SCons/scons/commit/12f24df0004ced8b91e758f29cd6396e60f37f5a.patch)
sha512sums=('f79b86bb09783767b3872cfb8efb665372714a604af2aaf3adc66eee63d3afe27bc6b2aab83813743c83f71c81c800d42842e916501787ba402ce2726dda9b44'
            '483655b0c5134095cb7099eb90b1f840eeff2b13681b5ef47171b46814bc39ce85f5b14eba5c267ed1af27f169a894e0299f224010c29b5b7fe8d3bab434a38e')

prepare() {
  cd "${pkgname}-${pkgver}"
# patch does not fix manpage location,  seems to make it worse.
#  patch -p1 -i ../scons-manpage-packaging-fix.patch
}

build() {
  cd "${pkgname}-${pkgver}"
  python scripts/scons.py BUILD_SYSTEM="archlinux" DEVELOPER="$pkgname" DATE="$(date -Ru${SOURCE_DATE_EPOCH:+d @$SOURCE_DATE_EPOCH})"
  python setup.py build
}

check_() {
  cd "${pkgname}-${pkgver}"
#  python runtest.py -a -t || echo "Tests passing with 'NO RESULT' count as failed."
}

package() {
  local py_ver=$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')
  cd "${pkgname}-${pkgver}"
  python setup.py install --prefix=/usr \
                          --skip-build \
                          --optimize=1 \
                          --install-data=/usr/share \
                          --root="$pkgdir"
  # strip $pkgdir from embedded paths:
  python -m compileall -d "/usr/lib/python${py_ver}" \
    "${pkgdir}/usr/lib/python${py_ver}"
  python -O -m compileall -d "/usr/lib/python${py_ver}" \
    "${pkgdir}/usr/lib/python${py_ver}"
  install -vDm 644 {LICENSE,LICENSE-local} -t "${pkgdir}/usr/share/licenses/${pkgname}/"
  install -vDm 644 {CHANGES,RELEASE}.txt README-package.rst \
    -t "${pkgdir}/usr/share/doc/${pkgname}/"

  # why are the man pages here?
  install -vdm 755 "${pkgdir}/usr/share/man/man1"
  mv "${pkgdir}/usr/share/"*.1 -t "${pkgdir}/usr/share/man/man1"

  cp -r build/doc/{HTML,PDF,TEXT} "${pkgdir}/usr/share/doc/${pkgname}"

  # remove docbook?
#  rm -vrf "${pkgdir}"/usr/lib/python${py_ver}/site-packages/SCons/Tool/docbook/
}