# Maintainer: Kaizhao Zhang <zhangkaizhao@gmail.com>

pkgname=python-rst2pdf
_pkgname=rst2pdf
pkgver=0.98
pkgrel=1
pkgdesc="Convert reStructured Text to PDF via ReportLab."
url="https://rst2pdf.org"
depends=(
  'python'
  'python-docutils'
  'python-jinja'
  'python-pygments'
  'python-reportlab'
  'python-smartypants'
)
makedepends=('python-setuptools')
optdepends=(
  'python-sphinx: sphinx'
  'python-wordaxe>=1.0: hyphenation'
  'python-svglib: SVG support'
  'python-aafigure>=0.4: aafigure support'
  'python-matplotlib: math support'
  'python-xhtml2pdf: raw HTML support'
)
arch=('any')
license=('MIT')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/rst2pdf/rst2pdf/archive/${pkgver}.tar.gz")
sha256sums=('22fb02032b3c2eed834b47f974755457a65958554543fd577680458f2e24816b')

build() {
  cd ${_pkgname}-${pkgver}
  python setup.py build
}

package() {
  cd ${_pkgname}-${pkgver}
  python setup.py install --root="${pkgdir}/" --optimize=1 --skip-build

  install -Dm644 CHANGES.rst "${pkgdir}/usr/share/doc/${pkgname}/CHANGES.rst"
  install -Dm644 CODE_OF_CONDUCT.rst "${pkgdir}/usr/share/doc/${pkgname}/CODE_OF_CONDUCT.rst"
  install -Dm644 Contributors.txt "${pkgdir}/usr/share/doc/${pkgname}/Contributors.txt"
  install -Dm644 MAINTAINERS.rst "${pkgdir}/usr/share/doc/${pkgname}/MAINTAINERS.rst"
  install -Dm644 README.rst "${pkgdir}/usr/share/doc/${pkgname}/README.rst"

  install -Dm644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"
}