# Maintainer: Your Name <youremail@domain.com>
pkgname=blobsaver
pkgver=2.5.5
pkgrel=1
pkgdesc="A GUI for saving SHSH blobs using tsschecker."
arch=('x86_64')
url="https://github.com/airsquared/blobsaver"
license=('GPL3')
depends=('java-runtime=8' 'java8-openjfx' 'bash') # 'archlinux-java-run')
makedepends=('java-environment=8' 'gradle' 'gendesk')
optdepends=('libimobiledevice: Get plugged in device information'
    'libirecovery: Utility to talk to iBoot/iBSS via USB')
source=("$pkgname-$pkgver.tar.gz::https://github.com/airsquared/blobsaver/archive/v2.5.5.tar.gz")
sha256sums=('559ab20b6450661da8b7d4996d9d08ae4ba9c8bf51a48f3775227347bac07694')

prepare() {
  cd "$pkgname-$pkgver"
  sed -i 's/"imobiledevice"/"imobiledevice-1.0"/' src/main/java/airsquared/blobsaver/app/natives/Libimobiledevice.java
}

build() {
  cd "$pkgname-$pkgver"
  gradle jar
}

package() {
  cd "$pkgname-$pkgver"
  gendesk -f -n --pkgname "$pkgname" --pkgdesc "$pkgdesc" \
    --exec="$pkgname" --categories=Utility --icon "$pkgname"
  install -Dm755 dist/linux/tsschecker -t "${pkgdir}/opt/$pkgname"
  install -Dm755 build/libs/blobsaver.jar -t "${pkgdir}/opt/$pkgname"
  echo "#!/usr/bin/env bash
  archlinux-java-run -a 8 -b 8 -- -jar /opt/blobsaver/blobsaver.jar
  " > $pkgname.sh
  install -Dm775 $pkgname.sh "$pkgdir/usr/bin/$pkgname"
  install -Dm644 $pkgname.desktop "$pkgdir/usr/share/applications/$pkgname.desktop"
}