# Maintainer: Balló György <ballogyor+arch at gmail dot com>

pkgname=gnome-passwordsafe
pkgver=3.99.2
pkgrel=2
pkgdesc="Password manager for GNOME which makes use of the KeePass v.4 format"
arch=(any)
url="https://gitlab.gnome.org/World/PasswordSafe"
license=(GPL3)
depends=(libhandy0 libpwquality python-gobject python-pykeepass)
makedepends=(git gobject-introspection meson)
_commit=d8661505a286d9e26d9b96c28767281a95831582  # tags/3.99.2
source=("git+https://gitlab.gnome.org/World/PasswordSafe.git/#commit=$_commit")
sha256sums=('SKIP')

pkgver() {
  cd PasswordSafe
  git describe --tags | sed 's/-/+/g'
}

prepare(){
  cd PasswordSafe
  # These patches are required to fix https://bugs.archlinux.org/task/68525
  # They can be removed after a new version releases
  git cherry-pick -n 63cf3ea57b4f1e3de7f96c4a021d1195cff892ee
  git cherry-pick -n 0e02d161e5e5ced2f7147d22f5323028fcb6f848
}

build() {
  arch-meson PasswordSafe build
  ninja -C build
}

check() {
  meson test -C build
}

package() {
  DESTDIR="$pkgdir" meson install -C build
}