# Maintainer: Filipe Laíns (FFY00) <lains@archlinux.org>

pkgname=yubioath-desktop
pkgdesc='Yubico Authenticator for Desktop'
pkgver=5.0.0
pkgrel=3
arch=('x86_64')
url="https://github.com/Yubico/$pkgname"
license=('BSD')
depends=('pcsclite' 'ccid' 'python-pyotherside' 'yubikey-manager' 
         'qt5-quickcontrols2' 'qt5-declarative' 'qt5-graphicaleffects')
makedepends=('swig' 'qt5-svg' 'libffi' 'openssl' 'qt5-base' 'git')
validpgpkeys=('8D0B4EBA9345254BCEC0E843514F078FF4AB24C3' # Dag Heyman <dag@yubico.com>
              '57A9DEED4C6D962A923BB691816F3ED99921835E' # Emil Lundberg <emil@yubico.com>
              )
source=("git+$url.git#tag=$pkgname-$pkgver?signed")
sha256sums=('SKIP')

build() {
  cd "$pkgname"

  qmake \
  PREFIX=/usr \
  QMAKE_CFLAGS_RELEASE="$CFLAGS" \
  QMAKE_CXXFLAGS_RELEASE="$CXXFLAGS" \
  QMAKE_LFLAGS_RELEASE="$LDFLAGS"
  
  make
}

package() {
    cd "$pkgname"

    make INSTALL_ROOT="$pkgdir" install

    install -Dm 644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"

    install -Dm 644 images/yubioath@2x.png "$pkgdir/usr/share/pixmaps/yubioath.png"
    install -Dm 755 resources/yubioath-desktop.desktop "$pkgdir/usr/share/applications/yubioath-desktop.desktop"
}