# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: BlackIkeEagle <ike DOT devolder AT gmail DOT com>
# Contributor: Valeriy Lyasotskiy <onestep@ukr.net>
# Contributor: Jan Willemson <janwil@hot.ee>
# Contributor: Hugo Ideler <hugoideler@dse.nl>
# Original PKGBUILD: Andre Naumann <anaumann@SPARCed.org>
# See http://bbs.archlinux.org/viewtopic.php?t=9318&highlight=fpc

pkgname=fpc
pkgver=3.2.0
pkgrel=1
pkgdesc="Free Pascal Compiler, Turbo Pascal 7.0 and Delphi compatible."
arch=('x86_64')
url="http://www.freepascal.org/"
license=('GPL' 'LGPL' 'custom')
backup=("etc/fpc.cfg")
depends=('ncurses' 'zlib' 'expat' 'binutils' 'make')
makedepends=(fpc)
options=(zipman staticlibs)
source=(fpc.tar.gz)
sha512sums=('ef7e9fafe5afe74a4dfa8102b458c58fc7b8b5750e0f1d4498e4ab9d62fda5947562962c6ff00e92f0a14688975fcc88e2231be0b9a6114599d31e0408ac098e')

build() {
  cd "$srcdir"/fpc
  pushd compiler
  fpcmake -Tall
  popd
  make build NOGDB=1
}

package() {
  cd "$srcdir"/fpc

  export HOME="$srcdir"

  make -j1 PREFIX="$pkgdir"/usr install NOGDB=1

  export PATH="$pkgdir"/usr/bin:$PATH

  install -Dm0644 "$srcdir"/fpc/rtl/COPYING.FPC "$pkgdir"/usr/share/licenses/${pkgname}/COPYING.FPC

  [ "$CARCH" = "x86_64" ] && ln -s /usr/lib/fpc/${pkgver}/ppcx64 "$pkgdir"/usr/bin/

  mkdir -p "$pkgdir"/etc
  "$pkgdir"/usr/lib/fpc/${pkgver}/samplecfg "$pkgdir"/usr/lib/fpc/${pkgver} "$pkgdir"/etc

  # use -fPIC by default
  echo -e "#ifdef cpux86_64\n# for x86_64 use -fPIC by default\n-Cg\n#endif" >> "$pkgdir/etc/fpc.cfg"

  #mv "$srcdir"/usr/man "$pkgdir"/usr/share/

  #find "$pkgdir"/etc/ -type f -exec sed -i "s|"$pkgdir"||g" {} \;
  #sed -e "s|$pkgdir||g" -i "$pkgdir/usr/lib/fpc/$pkgver/ide/text/fp.cfg"

}