# Maintainer: Bruno Pagani <archange@archlinux.org>

pkgbase=materia-kde
pkgname=(materia-kde kvantum-theme-materia)
pkgver=20190707
pkgrel=1
pkgdesc="Materia theme for KDE Plasma 5"
arch=(any)
url="https://github.com/PapirusDevelopmentTeam/${pkgbase}"
license=(GPL3)
options=(!strip)
source=("${url}/archive/${pkgver}/${pkgbase}-${pkgver}.tar.gz")
sha256sums=('a884697202dc697a96dc5a447029934acbb7bf2fdbc272cd5590ef9536a9f637')

package_materia-kde() {
    optdepends=('materia-gtk-theme: Matching GTK theme'
                'kvantum-theme-materia: Materia theme for Kvantum Qt style (recommended)')

    cd ${pkgbase}-${pkgver}
    install -d "${pkgdir}"/usr/share

    cp -r plasma "${pkgdir}"/usr/share
    cp -r aurorae "${pkgdir}"/usr/share
    cp -r color-schemes "${pkgdir}"/usr/share
    cp -r konsole "${pkgdir}"/usr/share
    cp -r yakuake "${pkgdir}"/usr/share
}

package_kvantum-theme-materia() {
    pkgdesc="Materia theme for KDE Plasma 5"
    depends=(kvantum-qt5)

    cd "${pkgbase}-${pkgver}/Kvantum"
    for d in *; do
        dest="$d";
        if [[ $dest != "Materia" ]]; then
            dest="${d#Materia}"
            dest="Materia-${dest,,}"
        fi

        install -dm755 "${pkgdir}/usr/share/themes/$dest"
        cp -r "$d" "${pkgdir}/usr/share/themes/$dest/Kvantum"

        if [[ $d != $dest ]]; then
            mv "${pkgdir}/usr/share/themes/$dest/Kvantum/"{$d,$dest}.kvconfig
            mv "${pkgdir}/usr/share/themes/$dest/Kvantum/"{$d,$dest}.svg
        fi
    done
}