# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgbase=nautilus
pkgname=(nautilus libnautilus-extension)
pkgver=3.30.2
pkgrel=2
pkgdesc="Default file manager for GNOME"
url="https://wiki.gnome.org/Apps/Nautilus"
arch=(x86_64)
license=(GPL)
depends=(libgexiv2 gnome-desktop gvfs dconf tracker nautilus-sendto gnome-autoar)
makedepends=(gobject-introspection packagekit git gtk-doc meson appstream-glib)
options=(!emptydirs)
_commit=09fd9171dbb3a4ecbac093710411314f83e6322e  # tags/3.30.2^0
source=("git+https://gitlab.gnome.org/GNOME/nautilus.git#commit=$_commit"
        "git+https://gitlab.gnome.org/GNOME/libgd.git"
        "fix_type_ahead_find.patch")
sha256sums=('SKIP'
            'SKIP'
            'b17639a79f9349c572c21315f2f74f9848bac3da0aa2166a311dbc533d3f1a1e')

prepare() {
  cd $pkgbase

  git submodule init
  git config --local submodule.subprojects/libgd.url "$srcdir/libgd"
  git submodule update

  patch -Np1 -i ../fix_type_ahead_find.patch
}

pkgver() {
  cd $pkgbase
  git describe --tags | sed 's/-/+/g'
}

build() {
  arch-meson $pkgbase build -D docs=true
  ninja -C build
}

check() {
  meson test -C build
}

package_nautilus() {
  depends+=(libnautilus-extension)
  groups=(gnome)

  DESTDIR="$pkgdir" meson install -C build

### Split libnautilus-extension

  mkdir -p libne/{lib,share}
  mv "$pkgdir"/usr/include libne
  mv "$pkgdir"/usr/lib/{girepository-1.0,libnautilus-extension*,pkgconfig} libne/lib
  mv "$pkgdir"/usr/share/{gir-1.0,gtk-doc} libne/share
}

package_libnautilus-extension() {
  pkgdesc="Library for extending the $pkgdesc"
  depends=(gtk3)
  mv libne "$pkgdir/usr"
}

# vim:set sw=2 et: