# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Kaiting Chen <kaitocracy@gmail.com>
# Contributor: Abhishek Dasgupta <abhidg@gmail.com>
# Contributor: Eric Belanger <eric@archlinux.org>
# Contributor: Jan Fader <jan.fader@web.de>
# Contributor: Mélanie Chauvel (ariasuni) <perso@hack-libre.org>

pkgname=fish
pkgver=2.7.1
pkgrel=2
pkgdesc='Smart and user friendly shell intended mostly for interactive use'
url='https://fishshell.com/'
arch=('x86_64')
license=('GPL2')
depends=('bc' 'ncurses' 'pcre2')
optdepends=(
  'python: for manual page completion parser and web configuration tool'
  'pkgfile: suggest packages to install when command is not found'
)
makedepends=('cmake' 'doxygen')
install=fish.install
source=(
  "${pkgname}-${pkgver}.tar.gz::https://github.com/fish-shell/fish-shell/archive/${pkgver}.tar.gz"
  'use-system-wcwidth.patch'
)
sha512sums=(
  '53eb8082812f28386b491ea18caa4a51ac66ead87fa78d5584275c66f1335b8705fad266170dc2ed6ee9e5d1febcdf0869c37ed2f95b58c10a74faf4ad95e610'
  'dfc0753cc81198027b139e3661be2d1e7ae5de9a970badc31ae618617960f86f7ae19e0928a7c258d6ed70ec6412500dbee220b5de49d7482954caf0b73ae629'
)

prepare() {
  cd fish-shell-${pkgver}
  echo ${pkgver} > version
  autoreconf --recursive
  patch -Np1 -i "$srcdir/use-system-wcwidth.patch"
}

build() {
  cd fish-shell-${pkgver}
  ./configure --prefix=/usr --sysconfdir=/etc --docdir=/usr/share/doc/fish \
    --without-included-pcre2
  make
}

package() {
  cd fish-shell-${pkgver}
  make DESTDIR="${pkgdir}" install
}