# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Sébastien Luttringer
# Contributor: xduugu
# Contributor: Ronald van Haren <ronald.archlinux.org>
# Contributor: Vesa Kaihlavirta

pkgname=awesome
pkgver=4.0
pkgrel=1
pkgdesc='Highly configurable framework window manager'
url='http://awesome.naquadah.org/'
arch=('i686' 'x86_64')
license=('GPL2')
depends=('cairo' 'dbus' 'gdk-pixbuf2' 'imlib2' 'libxkbcommon-x11' 'libxdg-basedir' 'lua'
         'lua-lgi' 'pango' 'startup-notification' 'xcb-util-cursor' 'xcb-util-keysyms'
         'xcb-util-wm' 'xcb-util-xrm' 'xorg-xmessage')
makedepends=('asciidoc' 'cmake' 'docbook-xsl' 'doxygen' 'imagemagick' 'ldoc' 'xmlto')
optdepends=('rlwrap: readline support for awesome-client'
            'dex: autostart your desktop files'
            'vicious: widgets for the Awesome window manager')
provides=('notification-daemon')
backup=('etc/xdg/awesome/rc.lua')
source=(https://github.com/awesomeWM/awesome-releases/raw/master/awesome-$pkgver.tar.xz{,.asc})
sha512sums=('80bdfe5f9166f5e9b0266cd630b48607d17605330d0f172666dbfa3f239ef04aeafafebe8949c3bf1c31a7bd372b60252d56c815048a24e015858585c3d0432b'
            'SKIP')
validpgpkeys=('2BB32F88FF3D1E76E682303F22E428EBCB8FCB06')

prepare() {
  cd ${pkgname}-${pkgver}
  mkdir -p build
}

build() {
  cd ${pkgname}-${pkgver}/build
  cmake .. \
    -DCMAKE_BUILD_TYPE=RELEASE \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DSYSCONFDIR=/etc \
    -DLUA_LIBRARY=/usr/lib/liblua.so.5.3
  make
}

package() {
  cd ${pkgname}-${pkgver}
  install -Dm 644 awesome.desktop "${pkgdir}/usr/share/xsessions/awesome.desktop"
  make -C build DESTDIR="${pkgdir}" install
}

# vim: ts=2 sw=2 et: