# $Id$
# Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
# Contributor: Xavier Devlamynck <magicrhesus@ouranos.be>

pkgbase=libxfce4ui
pkgname=(libxfce4ui-common libxfce4ui-gtk2 libxfce4ui-gtk3)
pkgver=4.12.1
pkgrel=2
pkgdesc="Commonly used Xfce widgets among Xfce applications"
arch=('i686' 'x86_64')
url="http://www.xfce.org/"
license=('GPL2')
depends=('libxfce4util' 'gtk2' 'gtk3' 'xfconf' 'libsm' 'startup-notification'
         'hicolor-icon-theme')
makedepends=('intltool' 'gtk-doc')
conflicts=('libxfce4ui')
install=$pkgbase.install
source=(http://archive.xfce.org/src/xfce/$pkgbase/${pkgver%.*}/$pkgbase-$pkgver.tar.bz2)
sha256sums=('3d619811bfbe7478bb984c16543d980cadd08586365a7bc25e59e3ca6384ff43')

build() {
  cd "$srcdir/$pkgbase-$pkgver"

  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --libexecdir=/usr/lib \
    --localstatedir=/var \
    --disable-static \
    --enable-gtk-doc \
    --disable-debug \
    --with-vendor-info='Arch Linux'
  make
}

package_libxfce4ui-common() {
  pkgdesc+=" (common files)" 
  depends=('hicolor-icon-theme')

  cd "$srcdir/$pkgbase-$pkgver"
  make DESTDIR="$pkgdir" install

  # Split libxfce4ui-gtk2 and libxfce4ui-gtk3
  [[ -d $srcdir/libxfce4ui-gtk ]] && rm -r "$srcdir/libxfce4ui-gtk/"
  mkdir "$srcdir"/libxfce4ui-gtk
  mv "$pkgdir"/usr/bin \
     "$pkgdir"/usr/include \
     "$pkgdir"/usr/lib \
     "$pkgdir"/usr/share/applications \
     "$srcdir/libxfce4ui-gtk/"
}

package_libxfce4ui-gtk2() {
  pkgdesc+=" (GTK2 version)" 
  depends=('libxfce4util' 'libxfce4ui-common' 'gtk2' 'xfconf' 'libsm'
           'startup-notification')

  cd "$srcdir"/libxfce4ui-gtk
  mkdir -p "$pkgdir"/usr/{include/xfce4,lib/pkgconfig,share}
  mv bin "$pkgdir/usr"
  mv include/xfce4/libxfce4kbd-private-2 "$pkgdir/usr/include/xfce4"
  mv include/xfce4/libxfce4ui-1 "$pkgdir/usr/include/xfce4"
  mv lib/libxfce4kbd-private-2.so* "$pkgdir/usr/lib"
  mv lib/libxfce4ui-1.so* "$pkgdir/usr/lib"
  mv lib/pkgconfig/libxfce4kbd-private-2.pc "$pkgdir/usr/lib/pkgconfig"
  mv lib/pkgconfig/libxfce4ui-1.pc "$pkgdir/usr/lib/pkgconfig"
  mv applications "$pkgdir/usr/share"
}

package_libxfce4ui-gtk3() {
  pkgdesc+=" (GTK3 version)" 
  depends=('libxfce4util' 'libxfce4ui-common' 'gtk3' 'xfconf' 'libsm'
           'startup-notification')

  cd "$srcdir"/libxfce4ui-gtk
  mkdir -p "$pkgdir"/usr/{include/xfce4,lib/pkgconfig}
  mv include/xfce4/libxfce4kbd-private-3 "$pkgdir/usr/include/xfce4"
  mv include/xfce4/libxfce4ui-2 "$pkgdir/usr/include/xfce4"
  mv lib/libxfce4kbd-private-3.so* "$pkgdir/usr/lib"
  mv lib/libxfce4ui-2.so* "$pkgdir/usr/lib"
  mv lib/pkgconfig/libxfce4kbd-private-3.pc "$pkgdir/usr/lib/pkgconfig"
  mv lib/pkgconfig/libxfce4ui-2.pc "$pkgdir/usr/lib/pkgconfig"
}

# vim:set ts=2 sw=2 et: