# Contributor: Jeremy Cowgar <cowgar.com: jeremy>
# Maintainer:  Jesse Jaara   <gmail.com:  jesse.jaara>

pkgname=euphoria
pkgver=4.1.0
pkgrel=1
pkgdesc="Fast interpreted or compiled general purpose programming language"
url="http://openeuphoria.org"
license=('custom:"OpenEuphoria License"')
source_i686+=(http://downloads.sourceforge.net/rapideuphoria/Euphoria/${pkgver}/${pkgname}-${pkgver}-Linux-ix86.tar.gz)
source_x86_64+=(http://downloads.sourceforge.net/rapideuphoria/Euphoria/${pkgver}/${pkgname}-${pkgver}-Linux-ix86-64.tar.gz)
arch=('i686' 'x86_64')
depends=('glibc')
depends_x86_64+=('lib32-glibc')
makedepends_x86_64+=('gcc-multilib')
changelog=ChangeLog

build() {
  ### We have a dirty tarball at the moment :(
  cd "${srcdir}"/${pkgname}-${pkgver}-Linux-*/source

  ./configure --prefix=/usr

  ## Thearded building is broken in this release. You can also do
  ## makepkg && makepkg -e, if you remove the -j1.
  make -j1
  make tools
}

package() {
  cd "${srcdir}"/${pkgname}-${pkgver}-Linux-*/source

  ## The installer cretes the bin dir too late :'( ##
  mkdir -p "${pkgdir}/usr/bin"
  # Base and Tool install
  make DESTDIR="${pkgdir}" install install-tools

  # Install our license file per ArchLinux spec
  mkdir -p "${pkgdir}/usr/share/licenses/${pkgname}"
  install -m 644 "${srcdir}"/${pkgname}-${pkgver}-Linux-*/License.txt "${pkgdir}/usr/share/licenses/${pkgname}/"

  # Make an initial eu.cfg
  cat > eu.cfg <<EOF
[all]
-i /usr/share/${pkgname}/include
EOF
  mkdir -p "${pkgdir}/etc/${pkgname}"
  install -m644 eu.cfg "${pkgdir}/etc/${pkgname}"
}

md5sums_i686=()
md5sums_x86_64=()
#md5sums_i686=('6ebd8bb45e5281c391ee928b52999ade')
#md5sums_x86_64=('dfc90304391f7c3a96d7b776380823e4')