# $Id: PKGBUILD 220280 2014-08-20 15:30:10Z svenstaro $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>

pkgbase=baloo4
pkgname=('baloo4' 'baloo4-akonadi' 'libbaloo4')
pkgver=4.14.0
pkgrel=2
pkgdesc="A framework for searching and managing metadata"
arch=('i686' 'x86_64')
url='https://projects.kde.org/projects/kde/kdelibs/baloo'
license=('LGPL')
depends=('kdepimlibs' 'xapian-core' 'kfilemetadata')
makedepends=('cmake' 'automoc4' 'boost')
source=("http://download.kde.org/stable/${pkgver}/src/${pkgname}-${pkgver}.tar.xz")
sha1sums=('6aa998d62f9f92c08a3eedc72b050fdb00e7bad0')

prepare() {
  mkdir build
}

build() {
  cd build
  cmake ../${pkgname}-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr
  make
}

package_baloo4() {
  depends=('libbaloo4')
  replaces=('baloo')
  provides=('baloo')
  conflicts=('baloo')
  install=${pkgname}.install

  cd build
  make DESTDIR="${pkgdir}" install

  rm -r "${pkgdir}"{/usr/bin/akonadi_baloo_indexer,/usr/include,/usr/lib,/usr/share/akonadi,/usr/share/kde4}
}

package_baloo4-akonadi() {
  depends=('libbaloo4') 

  cd build
  make DESTDIR="${pkgdir}" install 

  rm -r "${pkgdir}"{/etc,/usr/bin/baloo*,/usr/include,/usr/lib,/usr/share/{kde4,autostart,dbus-1,icons,polkit-1}}
}

package_libbaloo4() {
  depends=('kdepimlibs' 'xapian-core' 'kfilemetadata')

  cd build
  make DESTDIR="${pkgdir}" install

  rm -r "${pkgdir}"{/etc,/usr/bin,/usr/share/{akonadi,autostart,dbus-1,icons,polkit-1}}
}