# $Id: PKGBUILD 201550 2013-12-14 22:59:54Z heftig $
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
# Contributor: Douglas Soares de Andrade <douglas@archlinux.org>

pkgname=meld
pkgver=1.8.3
pkgrel=2
pkgdesc='Visual diff and merge tool'
url='http://meldmerge.org/'
license=('GPL')
arch=('any')
makedepends=('intltool' 'gnome-doc-utils')
depends=('pygtk' 'hicolor-icon-theme' 'desktop-file-utils')
optdepends=('pygtksourceview2: syntax highlighting'
            'python2-dbus: open a new tab in an already running instance'
            'python2-gconf: gnome integration')
source=("http://ftp.gnome.org/pub/gnome/sources/${pkgname}/${pkgver%.*}/${pkgname}-${pkgver}.tar.xz")
sha1sums=('b2321e45466a963cb7bd85e6b648c9648b35af52')

install=install
options=('!emptydirs')

prepare() {
	cd "${pkgname}-${pkgver}"
	sed -i 's/update-/#update-/' Makefile
	sed -i 's/env python/env python2/' bin/meld
	sed -i '1755s/.$/:Non resente"/' po/it.po       #fix https://bugs.archlinux.org/task/38148 
}

build() {
	cd "${pkgname}-${pkgver}"
	make PYTHON=/usr/bin/python2 prefix=/usr
}

package() {
	cd "${pkgname}-${pkgver}"
	make PYTHON=/usr/bin/python2 prefix=/usr DESTDIR="${pkgdir}" install
}