# $Id: PKGBUILD 99899 2013-10-31 02:21:39Z allan $
# Maintainer: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Brad Fanella <bradfanella@archlinux.us>
# Contributor: fnord0 [fnord0 <AT> riseup <DOT> net]
# Contributor: dninja <dninja@gmail.com>

pkgname=lorcon
pkgver=2.0.0.20091101
pkgrel=1
pkgdesc="Loss Of Radio CONnectivity: A generic library for injecting 802.11 frames"
url='http://802.11ninja.net/'
license=('GPL')
arch=('x86_64' 'i686')
depends=('libpcap')
makedepends=('git')
source=('git+https://code.google.com/p/lorcon/')
md5sums=('SKIP')

pkgver() {
  cd "${srcdir}/${pkgname}"
  major=$(cat Makefile.in | grep -E "^MAJOR " | sed 's/^.*= *//')
  minor=$(cat Makefile.in | grep -E "^MINOR " | sed 's/^.*= *//')
  tiny=$(cat Makefile.in | grep -E "^TINY " | sed 's/^.*= *//')
  version=$(cat Makefile.in | grep -E "^VERSION " | sed 's/^.*= *//')
  echo "${major}.${minor}.${tiny}.$version"
}

prepare() {
  cd "$srcdir/$pkgname"
  ./configure --prefix=/usr --mandir=/usr/share/man
}

build() {
  cd "$srcdir/$pkgname"
  make
}

package() {
  cd "$srcdir/$pkgname"
  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et: