# Maintainer: Alex Szczuczko <alex at szc dot ca>
# Contributor: Devin Cofer <ranguvar{AT]archlinux[DOT}us>
# Contributor: Imanol Celaya <ilcra1989@gmail.com>

pkgname=bmake
pkgver=20130904
pkgrel=1
pkgdesc="Portable version of the NetBSD 'make' build tool"
arch=('i686' 'x86_64')
url="http://www.crufty.net/help/sjg/bmake.html"
license=('BSD')
source=("http://www.crufty.net/ftp/pub/sjg/bmake-$pkgver.tar.gz")
sha256sums=('b13e729507b9675603eb8d1391a6a9cc9d0ff5751cebd2a1e4a6987ecbbbb69b')

prepare() {
    cd "$srcdir/$pkgname"

    # Add missing bsd.*.mk symlinks
    _links_orig="dep doc init lib links man nls obj own prog subdir"
    _links_new="dep doc inc init lib links man nls obj own prog subdir"
    sed -i -e "s/$_links_orig/$_links_new/" mk/install-mk
}
    
build() {
    rm -rf bmake-build
    mkdir bmake-build
    cd bmake-build

    sh ../bmake/boot-strap --prefix=/usr
}

package() {
    cd bmake-build

    # Fix directory permissions on install
    install -dm 755 "$pkgdir/usr/bin"
    install -dm 755 "$pkgdir/usr/share/man/cat1"

    sh ../bmake/boot-strap --prefix=/usr --install-destdir="$pkgdir" op=install
}