# $Id$
# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor: Jaroslaw Swierczynski <swiergot@aur.archlinux.org>
# Contributor: Roman Kyrylych <Roman.Kyrylych@gmail.com>
# Contributor: Rabyte <rabyte [at] gmail (dot) com>

pkgname=assaultcube
pkgver=1.2.0.0
pkgrel=2
pkgdesc='A realistic team oriented multiplayer FPS based on the Cube engine'
arch=('i686' 'x86_64')
url='http://assault.cubers.net/'
license=('ZLIB' 'custom')
depends=('sdl' 'sdl_mixer' 'sdl_image' 'openal' 'zlib' 'gcc-libs' 'libgl' 'desktop-file-utils')
makedepends=('mesa')
source=("http://downloads.sourceforge.net/actiongame/AssaultCube_v${pkgver}.tar.bz2"
        "http://downloads.sourceforge.net/actiongame/AssaultCube_v${pkgver}.source.tar.bz2"
        'assaultcube'
        'assaultcube-server'
        'assaultcube.desktop'
        'assaultcube.png'
        "http://repo-arm-download.archlinuxcn.org/core/os/$CARCH/curl-7.23.1-2-$CARCH.pkg.tar.xz")
md5sums=('73f3a4df81d44b9dc8953037afba0c56'
         '6238e9313a3d04dc3737302573a1af3c'
         '4f7d5bca891fb842efcb1df70d312b0e'
         'c66a71f5914d3949b7492ae96c08529e'
         'a37dfbe8263f4ef8fe41120196194eae'
         'f688c59ecee2ebc5c589720aa1480765')
install=assaultcube.install

if [[ $CARCH == "x86_64" ]]; then
  md5sums+=('7102bf9898a5ed2f812286ff6f062a7f')
else
  md5sums+=('06794f609ae25b75293816f191ebaf2a')
fi

build() {
  cd AssaultCube_v${pkgver}.source/source

  # We'll use official binaries for cheat protection or some stuff.
  # Upstream is strange.
  #make
}

package() {
  #cd ${pkgver}/source/src

  #install -Dm755 ac_client ${pkgdir}/usr/bin/ac_client
  #install -Dm755 ac_server ${pkgdir}/usr/bin/ac_server
  cd ${srcdir}/AssaultCube_v${pkgver}

  mkdir -p ${pkgdir}/usr/share/assaultcube/packages
  mkdir -p ${pkgdir}/usr/bin

  if [[ $CARCH == "x86_64" ]]; then
    cp bin_unix/linux_64_client ${pkgdir}/usr/bin/ac_client
    cp bin_unix/linux_64_server ${pkgdir}/usr/bin/ac_server
  else
    cp bin_unix/linux_client ${pkgdir}/usr/bin/ac_client
    cp bin_unix/linux_server ${pkgdir}/usr/bin/ac_server
  fi
  cp -rf config packages docs mods ${pkgdir}/usr/share/assaultcube
  install -Dm644 ${srcdir}/assaultcube.png ${pkgdir}/usr/share/pixmaps/assaultcube.png
  install -Dm644 ${srcdir}/assaultcube.desktop ${pkgdir}/usr/share/applications/assaultcube.desktop
  install -Dm644 docs/package_copyrights.txt ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
  install -Dm755 ${srcdir}/assaultcube ${pkgdir}/usr/bin/assaultcube
  install -Dm755 ${srcdir}/assaultcube-server ${pkgdir}/usr/bin/assaultcube-server

  # use libcurl with CURL_OPENSSL_3 support - Fix FS#37315
  install -Dm755 ${srcdir}/usr/lib/libcurl.so.4.2.0 ${pkgdir}/opt/assaultcube/libcurl.so.4.2.0
}

# vim: sw=2:ts=2 et: