# Maintainer: Christian Hesse <mail@eworm.de>
# Contributor: tobias <tobias at archlinux.org>
# Contributor: Aurelien Foret <orelien@chez.com>

pkgname=xfce4-clipman-plugin-git
pkgver=2012.11.23
pkgrel=1
pkgdesc="A clipboard plugin for the Xfce4 panel - git checkout"
arch=('i686' 'x86_64')
license=('GPL')
url="http://goodies.xfce.org/projects/panel-plugins/xfce4-clipman-plugin"
groups=('xfce4-goodies')
depends=('xfce4-panel' 'libunique' 'libxtst' 'qrencode')
conflicts=('xfce4-clipman-plugin')
provides=('xfce4-clipman-plugin')
makedepends=('intltool')
options=('!libtool')
install=xfce4-clipman-plugin.install
source=('git://git.xfce.org/panel-plugins/xfce4-clipman-plugin'
	'http://www.eworm.de/download/linux/xfce4-clipman-plugin-qrcode.patch')

pkgver() {
	cd xfce4-clipman-plugin/
	git describe --tags --long | sed 's|^[^0-9]*||;s|-|.|g'
}


build() {
	cd xfce4-clipman-plugin/

	# add QR Code support
	patch -Np1 < ${srcdir}/xfce4-clipman-plugin-qrcode.patch

	# fix automake
	sed -i 's/^AM_CONFIG_HEADER/AC_CONFIG_HEADERS/' configure.ac.in

	./autogen.sh
	sed -i 's|$(TARGET_DIR)/C/media|$(docdir)/html/C/media|' doc/Makefile.in
	./configure --prefix=/usr \
		--sysconfdir=/etc \
		--libexecdir=/usr/lib \
		--localstatedir=/var \
		--disable-static \
		--enable-unique \
		--enable-maintainer-mode \
		--disable-debug
	make
}

package() {
	cd xfce4-clipman-plugin/

	make DESTDIR="${pkgdir}" install
}

sha256sums=('SKIP'
            '3020c3f88d4baf3a0b657db680fd5a1cb6952755d628654c005283c2662ff926')