# $Id: PKGBUILD 76685 2012-09-26 20:08:25Z dwallace $
# Maintainer: Daniel Wallace <danielwallace at gtmanfred dot com>
# Contributor: Alfredo Palhares <masterkorp@masterkorp.net>

pkgname=hub
_pkgdir=defunkt-hub-16b388a
pkgver=1.10.2
pkgrel=2
pkgdesc="cli interface for Github"
arch=('any')
url="http://defunkt.io/hub"
depends=('git' 'ruby')
license=('MIT')
source=("$pkgname.tar.gz::https://github.com/defunkt/hub/tarball/v$pkgver")
md5sums=('12357b7542d1caf4ec049343e8564057')

build() {
  cd "$_pkgdir"

  rake standalone
}

package() {
  cd "$_pkgdir"

  install -Dm755 'hub' "$pkgdir/usr/bin/hub"

  # completion
  install -Dm644 "etc/hub.bash_completion.sh" "$pkgdir/usr/share/bash-completion/completions/hub"
  install -Dm644 "etc/hub.zsh_completion" "$pkgdir/usr/share/zsh/site-functions/_hub"

  # doc
  install -Dm644 "man/$pkgname.1" "$pkgdir/usr/share/man/man1/$pkgname.1"

  # extra git hooks
  install -dm755 "$pkgdir/usr/share/doc/$pkgname"
  cp -dpr --no-preserve=ownership git-hooks/ "$pkgdir/usr/share/doc/$pkgname"

  # license
  install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}