# $Id: PKGBUILD 157819 2012-04-30 04:19:30Z foutrelis $
# Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
# Contributor: Xavier Devlamynck <magicrhesus@ouranos.be>

pkgname=libxfce4ui
pkgver=4.10.0
pkgrel=2
pkgdesc="Commonly used Xfce widgets among Xfce applications"
arch=('i686' 'x86_64')
url="http://www.xfce.org/"
license=('GPL2')
depends=('libxfce4util' 'gtk2' 'xfconf' 'libsm' 'startup-notification'
         'hicolor-icon-theme')
makedepends=('intltool' 'gtk-doc')
#replaces=('libxfcegui4') - later when all is ported
options=('!libtool')
install=libxfce4ui.install
source=(http://archive.xfce.org/src/xfce/$pkgname/4.10/$pkgname-$pkgver.tar.bz2
        enable-shift-modifier-in-shortcut-dialog.patch
        enable-shift-modifier-in-shortcut-grabber.patch)
md5sums=('6df1ce474a3d4885aee31cda9dbc9192'
         '52fd66799c91e9e51c1ab29b0780f200'
         '269adeff777854daf1dfb2afe5706d0e')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  patch -p1 -i "$srcdir/enable-shift-modifier-in-shortcut-dialog.patch"
  patch -p1 -i "$srcdir/enable-shift-modifier-in-shortcut-grabber.patch"

  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --libexecdir=/usr/lib \
    --localstatedir=/var \
    --disable-static \
    --enable-gtk-doc \
    --disable-debug \
    --with-vendor-info='Arch Linux'
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et: