# $Id: $
# Contributor: Vinycius Maia <suportevg@uol.com.br>
# Contributor: Alexander Fehr <pizzapunk gmail com>
# Contributor: Olivier Duclos <oliwer@free.fr>
# Maintainer : Daniel J Griffiths <griffithsdj@archlinux.us>

pkgname=volwheel
pkgver=0.2.8
pkgrel=2
pkgdesc="Tray icon to change volume with the mouse"
arch=('any')
url="http://oliwer.net/b/volwheel.html"
license=('GPL3')
depends=('perl-gtk2-trayicon' 'hicolor-icon-theme')
optdepends=("alsa-utils: for ALSA support"
	    "oss: for OSS support")
install=volwheel.install
source=(http://olwtools.googlecode.com/files/${pkgname}-${pkgver}.tar.gz)
md5sums=('aee73416972c4029dfb6a6048dcf0905')

package() {
	cd ${srcdir}/${pkgname}-${pkgver}
	package="volwheel"
	destdir="${pkgdir}"
	prefix="/usr"
	
	path="${destdir}/${prefix}"
	bindir="${path}/bin"
	libdir="${path}/lib/${package}"
	datadir="${path}/share/${package}"
	
	hicolor="${destdir}/usr/share/icons/hicolor/scalable/apps"
	desktop="${destdir}/usr/share/applications"
	
	if [ "${prefix}" != "/usr/local" ]; then
		sed -i 's/\/usr\/local/\/usr/g' volwheel
		sed -i 's/${prefix}/\/usr/g' volwheel
	else
		sed -i 's/${prefix}/\/usr\/local/g' volwheel
	fi
	
	install -v -d {$bindir,$libdir,$datadir,$hicolor,$desktop}
	install -v -m755 volwheel ${bindir}
	install -v -m644 lib/* ${libdir}
	cp -v -r icons ${datadir}/
	install -v -m644 icons/volwheel.svg $hicolor
	install -v -m644 volwheel.desktop $desktop
}