# $Id$
# Maintainer:  Lukas Fleischer <archlinux@cryptocrack.de>
# Contributor: Vesa Kaihlavirta <vesa@archlinux.org>
# Contributor: Sarah Hay <sarahhay@mb.sympatico.ca>
# Contributor: Tom Burdick <thomas.burdick@wrightwoodtech.com>
# Contributor: Ricardo Catalinas Jiménez <jimenezrick@gmail.com>

pkgname=erlang
pkgver=R15B01
pkgrel=2
pkgdesc='A general-purpose concurrent functional programming language developed by Ericsson'
arch=(i686 x86_64)
url='http://www.erlang.org'
license=('custom')
depends=('ncurses' 'glibc')
makedepends=('java-environment' 'perl' 'openssl' 'wxgtk' 'unixodbc' 'mesa')
optdepends=('wxgtk: for wx support'
            'mesa: for wx support'
            'unixodbc: for database support'
            'java-environment: for Java support')
source=("http://www.erlang.org/download/otp_src_$pkgver.tar.gz"
        "http://www.erlang.org/download/otp_doc_man_$pkgver.tar.gz")
md5sums=('f12d00f6e62b36ad027d6c0c08905fad'
         'd87412c2a1e6005bbe29dfe642a9ca20')

build() {
  cd "$srcdir/otp_src_$pkgver"
  ./configure --prefix=/usr --enable-smp-support #--enable-native-libs
  make
}

package() {
  cd "$srcdir/otp_src_$pkgver"
  make DESTDIR="$pkgdir" install

  # Install documentation
  install -d "$pkgdir/usr/share/doc/erlang"
  install -m644 "$srcdir/otp_src_$pkgver"/README.md \
    "$srcdir"/{README,COPYRIGHT} "$pkgdir/usr/share/doc/erlang"

  # Install compressed man pages
  for page in "$srcdir/man/man?/*"
  do
    gzip $page
  done
  cp -r "$srcdir/man" "$pkgdir/usr/lib/erlang"

  # Install license
  install -Dm644 "$srcdir/otp_src_$pkgver/EPLICENCE" \
    "$pkgdir/usr/share/licenses/$pkgname/EPLICENCE"
}