# $Id: PKGBUILD 109708 2011-02-11 22:45:33Z eric $
# Maintainer : Eric Bélanger <eric@archlinux.org>
# Maintainer : Aaron Griffin <aaron@archlinux.org>
# Contributor: SpepS <dreamspepser at yahoo dot it>

pkgname=bash-completion
pkgver=1.3
pkgrel=3
pkgdesc="Programmable completion for the bash shell"
arch=('any')
url="http://bash-completion.alioth.debian.org/"
license=('GPL')
depends=('bash')
source=("http://bash-completion.alioth.debian.org/files/$pkgname-$pkgver.tar.bz2"
        "extramodules.patch")
md5sums=('a1262659b4bbf44dc9e59d034de505ec'
         '78e11e7e4aacc55e5d1dde9eb72c0db3')
sha1sums=('6a46b93f44c56cc336632ab28d90c0595fbcc98f'
          '027b45ac6438674982fce3b5315054b9e89fba5e')

build() {
  cd "$srcdir/$pkgname-$pkgver"

  # Add support for extramodules in module_init_tools (FS#XXXXX)
  patch -p1 -i "$srcdir/${source[1]}"

  ./configure --prefix=/usr \
              --sysconfdir=/etc
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make DESTDIR="$pkgdir/" install

  rm -rf "$pkgdir/etc/profile.d"

  # Doesn't work on Arch Linux and cause problems (FS#20112)
  rm "$pkgdir/etc/bash_completion.d/service"
}