# $Id: PKGBUILD 110634 2011-02-20 20:50:17Z angvp $
# Maintainer: Angel Velasquez <angvp@archlinux.org>
# Contributor: Douglas Soares de Andrade <douglas@archlinux.org>
pkgbase=python-nose
pkgname=(python-nose python2-nose python-nose-doc)
pkgver=1.1.2
pkgrel=4
pkgdesc="A discovery-based unittest extension"
arch=('any')
url="http://www.somethingaboutorange.com/mrl/projects/nose/"
license=('LGPL2')
source=("http://pypi.python.org/packages/source/n/nose/nose-${pkgver}.tar.gz")
depends=('python' 'python-distribute' 'python2' 
        'python2-distribute' 'python-sphinx')
# conflicts=('python-nose')

build() {
    cd "$srcdir/nose-$pkgver"
    sed -i -e "s:man/man1:share/man/man1:g" setup.py
    cp -r "$srcdir/nose-$pkgver" "$srcdir/nose-$pkgver-py2-build"
}

package_python-nose() {
    depends=('python' 'python-distribute')
    cd "$srcdir/nose-$pkgver"
    rm -rf build/
    python setup.py install --prefix=/usr --root="$pkgdir"
}
package_python2-nose() {
    pkgdesc="A discovery-based unittest extension. Python 2 version"
    depends=('python2' 'python2-distribute')
    
    cd "$srcdir/nose-$pkgver-py2-build"
    rm -rf build/
    python2 setup.py install --prefix=/usr --root="$pkgdir"
    rm -rf "$pkgdir/usr/bin/nosetests" "$pkgdir"/usr/share
}
package_python-nose-doc(){
    pkgdesc="Nose documentation and examples"
    cd "$srcdir/nose-$pkgver/doc"
    make html
    mkdir -p "$pkgdir/usr/share/doc/python-nose"
    cp -r .build/html "$pkgdir/usr/share/doc/python-nose"
    cp -r ../examples "$pkgdir/usr/share/doc/python-nose"
}
md5sums=('144f237b615e23f21f6a50b2183aa817')