# $Id: PKGBUILD 138476 2011-09-24 16:46:30Z stephane $
# Maintainer: Eric Bélanger <eric@archlinux.org>
# Contributor: Liganic <liganic-aur@gmx.net>

pkgname=opencollada-svn
pkgver=863
pkgrel=2
pkgdesc="Stream based reader and writer library for COLLADA files"
arch=('i686' 'x86_64')
license=('MIT')
url="https://code.google.com/p/opencollada/"
depends=('pcre' 'libxml2')
makedepends=('cmake')
provides=('opencollada')
conflicts=('opencollada')
options=('!makeflags')
source=(ftp://ftp.archlinux.org/other/${pkgname}/${pkgname}-${pkgver}.tar.xz
        24747_optional_input_set_141.patch 24747_optional_input_set_150.patch)
sha1sums=('5ba6e55146fc86db7c22e2a8c48bd85f1b837dc4'
          '3feafc9f46b6e7b4bd4f35dec2ae777c6fa8bdf2'
          'ce50a2d9440bc686720e11ea9b88d6483e435061')

# source PKGBUILD && mksource
mksource() {
  [[ -x /usr/bin/svn ]] || (echo "svn not found. Install subversion." && return 1)
  _svnver=${pkgver}
  _svntrunk="http://opencollada.googlecode.com/svn/trunk"
  _svnmod="$pkgname-$pkgver"
  mkdir ${pkgname}-${pkgver}
  pushd ${pkgname}-${pkgver}
  svn co ${_svntrunk} --config-dir ./ -r ${_svnver} ${_svnmod}
  find . -depth -type d -name .svn -exec rm -rf {} \;
  tar -cJf ../${pkgname}-${pkgver}.tar.xz ${pkgname}-${pkgver}/*
  popd
  rm -r ${pkgname}-${pkgver}
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  patch -p0 -i ../24747_optional_input_set_141.patch
  patch -p0 -i ../24747_optional_input_set_150.patch
  sed -i "s|/usr/local|${pkgdir}/usr|" Makefile

  mkdir build
  cd build
  cmake .. \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release \
    -DUSE_STATIC=OFF \
    -DUSE_SHARED=ON
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}/build"
  make DESTDIR="${pkgdir}" install
  install -D -m644 ../COLLADAMaya/LICENSE.TXT "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}