# $Id: PKGBUILD 7981 2010-01-13 18:45:36Z dgriffiths $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: durbatuluk <dvdscripter@gmail.org>
# Contributor: Steven Ponsford <sp4rchy@archlinux.us>

pkgname=blackbox
pkgver=0.70.1
pkgrel=9
pkgdesc="A window manager for X11"
arch=('i686' 'x86_64')
depends=('libxft' 'libxext' 'xorg-server')
license=('MIT')
options=('!libtool')
source=(http://downloads.sourceforge.net/blackboxwm/$pkgname-$pkgver.tar.gz
	gcc4.3.patch textpropertytostring-unconditional.diff bbdock.patch bsetbg-feh.patch)
url="http://blackboxwm.sourceforge.net/"
md5sums=('2d173b95ca5e64ef478c6a5d2deee9df'
         'bc7a1335d77cdeb6f85cba4d01e68e63'
         '3b92ad246f07126dd55ae9634d6e875e'
         '69c5a5e981b087b2d8267cab996b48dd'
         'e7fb0d5bfd95820c0194ec73df66dadc')

build() {
  cd $startdir/src/$pkgname-$pkgver

  patch -Np1 -i ../gcc4.3.patch || return 1
  patch -Np1 -i ../textpropertytostring-unconditional.diff || return 1
  patch -Np0 -i ../bbdock.patch || return 1
  patch -Np0 -i ../bsetbg-feh.patch || return 1

  ./configure --prefix=/usr --mandir=/usr/share/man
  make || return 1
  make DESTDIR=$startdir/pkg install

  install -D -m644 LICENSE $startdir/pkg/usr/share/licenses/$pkgname/LICENSE
}