# $Id$
# Maintainer: Alexander Fehr <pizzapunk gmail com>
# Contributor: Andrew Simmons <andrew.simmons@gmail.com>
# Contributor: Tetsumaki <http://goo.gl/YMBdA>

pkgname=xarchiver
pkgver=0.5.2
pkgrel=1
pkgdesc="GTK+ frontend to various command line archivers"
arch=('i686' 'x86_64')
url="http://xarchiver.xfce.org/"
license=('GPL')
groups=('xfce4-goodies')
depends=('gtk2' 'desktop-file-utils' 'hicolor-icon-theme')
makedepends=('intltool')
optdepends=('tar: TAR support'
            'gzip: GZIP support'
            'bzip2: BZIP2 support'
            'zip: ZIP support'
            'unzip: ZIP support'
            'unrar: RAR support'
            'p7zip: 7z support'
            'arj: ARJ support'
            'lha: LHA support'
            'lzma-utils: LZMA support'
            'lzop: LZOP support')
options=('!libtool')
install=xarchiver.install
source=(http://downloads.sourceforge.net/xarchiver/xarchiver-${pkgver}.tar.bz2
        fix-7z.patch)
sha256sums=('cea932ff9d505969201fd502470bbebbc5726ab3d6765e142fc8295aa677ad2a'
            'b4970bb8b5d2563cb1261e85e5a9351480bd0e28339e2b8180d30748ac194c3a')

build() {
  cd "${srcdir}/xarchiver-${pkgver}/src"
  patch -Np0 -i "${srcdir}/fix-7z.patch"

  cd "${srcdir}/xarchiver-${pkgver}"
  ./configure --prefix=/usr --libexecdir=/usr/lib/xfce4
  make
}

package () {
  cd "${srcdir}/xarchiver-${pkgver}"
  make DESTDIR="${pkgdir}" install
}