# $Id: PKGBUILD 95257 2010-10-17 20:17:04Z ibiru $
# Maintainer: Jan de Groot <jgc@archlinux.org>
# Contributor: Douglas Soares de Andrade <dsa@aur.archlinux.org>
# Contributor: Angel 'angvp' Velasquez <angvp[at]archlinux.com.ve> 

pkgname=python3-numpy
pkgver=1.5.0
pkgrel=2
pkgdesc="Scientific tools for Python"
arch=('i686' 'x86_64')
license=('custom')
url="http://numpy.scipy.org/"
depends=('lapack' 'python3')
makedepends=('gcc-fortran')
source=(http://downloads.sourceforge.net/numpy/numpy-${pkgver}.tar.gz
        python3.patch
)
md5sums=('3a8bfdc434df782d647161c48943ee09'
         '5623437d420f0094991d025b66e9d794')

build() {
  cd "${srcdir}/numpy-${pkgver}"
  patch -Np0 -i "${srcdir}/python3.patch"

  export Atlas=None
  export LDFLAGS="$LDFLAGS -shared"
  python setup.py config_fc --fcompiler=gnu95 build
}

package() {
  cd "${srcdir}/numpy-${pkgver}"
  python setup.py config_fc --fcompiler=gnu95 install --prefix=/usr --root="${pkgdir}"
  
  install -D -m644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}