# $Id: PKGBUILD 94606 2010-10-08 18:17:20Z andyrtr $
# Maintainer: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>

pkgname=sqlite3
_amalgamationver=3070400
_amalgamationver2=${_amalgamationver/00/}
pkgver=${_amalgamationver2//0/.}
pkgrel=1
pkgdesc="A C library that implements an SQL database engine"
arch=('i686' 'x86_64')
license=('custom')
url="http://www.sqlite.org/"
depends=('readline>=6.0.00')
makedepends=('tcl')
conflicts=('sqlite')
replaces=('sqlite')
source=(http://www.sqlite.org/sqlite-tea-${_amalgamationver}.tar.gz # tarball of the amalgamation together with a Tcl Extension Architecture (TEA) compatible configure script and makefile
	http://www.sqlite.org/sqlite-doc-${_amalgamationver}.zip
	license.txt)
options=(!libtool)
md5sums=('75ff26334a5345caf2c0875da82bd918'
         'c38a4aae9cf6e8921ba7ad48a9301288'
         'c1cdbc5544034d9012e421e75a5e4890')

build() {
  cd ${srcdir}/sqlite-tea-${_amalgamationver}
  
  # check generic/tclsqlie3.c for possible settings
  export CFLAGS="$CFLAGS -DSQLITE_ENABLE_FTS3=1 -DSQLITE_ENABLE_COLUMN_METADATA=1 -DSQLITE_ENABLE_UNLOCK_NOTIFY -DSQLITE_SECURE_DELETE -DSQLITE_THREADSAFE "
  ./configure --prefix=/usr
  make
}

package() {
  cd ${srcdir}/sqlite-tea-${_amalgamationver}
  make DESTDIR=${pkgdir} install
#  install -Dm0644 sqlite3.1 ${pkgdir}/usr/share/man/man1/sqlite3.1

  # license
  install -Dm644 ${srcdir}/license.txt ${pkgdir}/usr/share/licenses/${pkgname}/license.txt
}