# $Id: PKGBUILD 94606 2010-10-08 18:17:20Z andyrtr $
# Maintainer: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>

pkgname=sqlite3
pkgver=3.7.3
pkgrel=1
pkgdesc="A C library that implements an SQL database engine"
arch=('i686' 'x86_64')
license=('custom')
url="http://www.sqlite.org/"
depends=('readline>=6.0.00')
makedepends=('tcl')
conflicts=('sqlite')
replaces=('sqlite')
source=(
    http://www.sqlite.org/sqlite-amalgamation-"$pkgver".tar.gz
    license.txt)
options=(!libtool)

build() {
  cd "$srcdir/sqlite-$pkgver"
  export LTLINK_EXTRAS="-ldl"
  export CFLAGS="$CFLAGS -DSQLITE_ENABLE_FTS3=1 -DSQLITE_ENABLE_COLUMN_METADATA=1 -DSQLITE_ENABLE_UNLOCK_NOTIFY -DSQLITE_SECURE_DELETE"

  ./configure --prefix=/usr \
    --enable-threadsafe \
    --disable-static

  # rpath removal
  sed -i 's|^hardcode_libdir_flag_spec=.*|hardcode_libdir_flag_spec=""|g' libtool
  sed -i 's|^runpath_var=LD_RUN_PATH|runpath_var=DIE_RPATH_DIE|g' libtool

  make
}


package() {
  cd "$srcdir/sqlite-$pkgver"
  make DESTDIR="$pkgdir" install
  install -Dm0644 sqlite3.1 "$pkgdir/usr/share/man/man1/sqlite3.1"

  # license
  install -Dm644 "$srcdir/license.txt" "$pkgdir/usr/share/licenses/$pkgname/license.txt"
}

md5sums=('74fe78b264f1c434c4b159d45b78e9b7'
         'c1cdbc5544034d9012e421e75a5e4890')