# $Id: PKGBUILD 24266 2009-01-15 19:53:01Z giovanni $
# Maintainer: Juergen Hoetzel <juergen@archlinux.org> 
# Contributors: William Rea <sillywilly@gmail.com>, 
# Bjorn Lindeijer <bjorn@lindeijer.nl>

pkgname=cegui
pkgver=0.7.1
pkgrel=1
pkgdesc="A free library providing windowing and widgets for graphics APIs/engines"
arch=('i686' 'x86_64')
url="http://crayzedsgui.sourceforge.net"
options=('!libtool')
license=('MIT')
depends=('pcre' 'expat' 'xerces-c' 'libxml2' 'fribidi' 'freetype2' 'glew'
         'silly' 'devil' 'freeimage' 'lua')
source=("http://downloads.sourceforge.net/project/crayzedsgui/CEGUI Mk-2/$pkgver/CEGUI-$pkgver.tar.gz")
md5sums=('0a2815d5204e3c5510884ab62285da97')

build() {
  cd $srcdir/CEGUI-$pkgver

  sed -i 's/ilLoadL=no/ilLoadL=yes/' configure

  ./configure --prefix=/usr --sysconfdir=/etc --disable-external-tinyxml \
    --enable-bidirectional-text --enable-toluacegui --disable-external-toluapp \
    --disable-samples --with-default-image-codec=SILLYImageCodec \
    --with-default-xml-parser=ExpatParser

  make
}

package() {
  cd $srcdir/CEGUI-$pkgver
  make DESTDIR=$pkgdir install
  install -Dm644 doc/COPYING $pkgdir/usr/share/licenses/$pkgname/COPYING
}