# $Id: PKGBUILD 8862 2010-01-22 03:01:39Z dgriffiths $
# Maintainer: Paulo Matias <matiasΘarchlinux-br·org>
# Contributor: Leslie P. Polzer <polzerΘgnu·org>
# Contributor: erm67 <erm67Θyahoo·it>

pkgname="djview4"
pkgver=4.5
pkgrel=11
pkgdesc="DJVU viewer (Qt4 version)"
url="http://djvu.sourceforge.net/"
license=('GPL')
arch=('i686' 'x86_64')
depends=('qt>=4.1' 'openssl' 'libdjvu>=3.5.19')
install=djview4.install
source=("http://downloads.sourceforge.net/djvu/$pkgname-$pkgver.tar.gz")
md5sums=('0461a26dbcac33dcc5eb7955ac357504')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  QTDIR=/usr
  ./configure --prefix=/usr      \
              --disable-nsdejavu || return 1
  make || return 1
  make DESTDIR="$pkgdir" LN_S=false install

  install -m755 \
          -d ${pkgdir}/usr/share/icons/hicolor/{32x32,64x64}/apps
  install -m755 -d ${pkgdir}/usr/share/pixmaps
  install -m755 -d ${pkgdir}/usr/share/applications

  install -m644 ${pkgdir}/usr/share/djvu/djview4/desktop/hi32-djview4.png \
             ${pkgdir}/usr/share/icons/hicolor/32x32/apps/djvulibre-djview4.png
  install -m644 ${pkgdir}/usr/share/djvu/djview4/desktop/hi64-djview4.png \
             ${pkgdir}/usr/share/icons/hicolor/64x64/apps/djvulibre-djview4.png
  install -m644 ${pkgdir}/usr/share/djvu/djview4/desktop/hi64-djview4.png \
             ${pkgdir}/usr/share/pixmaps/djvulibre-djview4.png
  install -m644 \
           ${pkgdir}/usr/share/djvu/djview4/desktop/djvulibre-djview4.desktop \
           ${pkgdir}/usr/share/applications
  rm -fr ${pkgdir}/usr/share/djvu/djview4/desktop
}