# $Id: PKGBUILD 60271 2009-12-02 16:31:21Z giovanni $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Kevin Piche <kevin@archlinux.org>
# Contributor: Manolis Tzanidakis <manolis@archlinux.org>

pkgname=cpufreqd
pkgver=20091213
pkgrel=1
pkgdesc="A small daemon to adjust cpu speed (and indeed voltage)"
arch=('i686' 'x86_64')
url="http://sourceforge.net/projects/cpufreqd"
license=('GPL2')
depends=('cpufrequtils')
makedepends=('git' 'pkgconfig')
install="$pkgname.install"
backup=(etc/cpufreqd.conf)
options=('!libtool')
source=('cpufreqd')
md5sums=('ae7b0ec1e8e9f9e7f05fb83749af4ed4')

_gitroot="git://git.kamineko.org/cpufreqd.git"

build() {
  msg "Connecting to GIT server..."
  if [[ -d $srcdir/$pkgname-$pkgver ]]; then
    cd $srcdir/$pkgname-$pkgver && git pull origin || return 1
  else
    git clone $_gitroot $srcdir/$pkgname-$pkgver || return 1
    cd $srcdir/$pkgname-$pkgver
  fi

  msg "GIT checkout done or server timeout"
  
  ./prepare.sh
  ./configure --prefix=/usr --sysconfdir=/etc
  make || return 1
  make check
  make DESTDIR=$pkgdir install

  install -D -m 755 $srcdir/cpufreqd $pkgdir/etc/rc.d/cpufreqd || return 1
}