# $Id: PKGBUILD 39014 2009-05-11 06:56:35Z tpowa $
# Maintainer: Tom Killian <tom@arclinux.org>

pkgname=openswan
pkgver=2.6.23
pkgrel=1
pkgdesc="Open Source implementation of IPsec for the Linux operating system"
url="http://www.openswan.org"
license=('GPL' 'custom')
arch=('i686' 'x86_64')
depends=('iproute' 'gmp' 'perl')
makedepends=('xmlto' 'docbook-xsl')
options=(!docs) #HTML docs do not build anyway
backup=(etc/ipsec.conf
        etc/ipsec.d/policies/{block,clear,clear-or-private,private,private-or-clear})
source=(http://www.openswan.org/download/openswan-$pkgver.tar.gz
        openswan.rc.d)
md5sums=('c83053471e639bf3b97e3cf7796b7e83'
         '543d84162761b9cc9ec319e938c4dd2a')

build() {
  # Create /etc/rc.d for init script, and license directory
  mkdir -p $pkgdir/{etc/rc.d,usr/share/licenses/openswan}

  cd $srcdir/openswan-$pkgver

  # Change install paths to Arch defaults
  sed -i 's|/usr/local|/usr|;s|libexec/ipsec|lib/openswan|;s|lib/ipsec|lib/openswan|' Makefile.inc

  # Custom compiler flags break the build
  unset CFLAGS

  make programs || return 1
  make DESTDIR=$pkgdir install

  # Remove SysV rc*.d directories
  rm -r $pkgdir/etc/rc[0-6].d

  # Change permissions in /var
  chmod 755 $pkgdir/var/run/pluto
  
  # Copy License
  cp LICENSE $pkgdir/usr/share/licenses/openswan
  
  # Install init script
  install -Dm755 ../openswan.rc.d $pkgdir/etc/rc.d/openswan
  # fix manpages
  mv $pkgdir/usr/man $pkgdir/usr/share/

  # fix perms
  find $pkgdir/usr/share -type f -exec chmod 644 {} +
  find $pkgdir/etc/ipsec.d/{examples,policies} -type f -exec chmod 644 {} +
  chmod 644 $pkgdir/etc/ipsec.conf
}