# $Id: PKGBUILD 37097 2009-04-30 21:35:49Z paul $
# Contributor: Andrew Wright <andreww@photism.org>
# Contributor: Andreas W. Hauser <andy-aur@splashground.de>
# Maintainer: Paul Mattal <paul@archlinux.org>

pkgname=eclipse
pkgver=3.4.2
pkgrel=1
pkgdesc="An IDE for Java and other languages"
arch=('i686' 'x86_64')
url="http://eclipse.org"
depends=('java-environment' gtk2 unzip xulrunner 'desktop-file-utils')
install=eclipse.install
makedepends=(zip)
license=("EPL/1.1")
if [ "$CARCH" = "x86_64" ]; then
    _arch=-x86_64
md5sums=('e068a144117bf83a3a4ef62022f47af6'
         '78db5f9dfd844288afd49e0f357dd539'
         'cbf880d22bfd4a34c5f6433007ed90f2'
         'ee66a334bc443fd23ad9bc080dc6ea69')
else
md5sums=('a131aa4fc6c858be4fc17f6d4bdb7089'
         '78db5f9dfd844288afd49e0f357dd539'
         'cbf880d22bfd4a34c5f6433007ed90f2'
         'ee66a334bc443fd23ad9bc080dc6ea69')
fi
source=(ftp://ftp.osuosl.org/pub/eclipse/eclipse/downloads/drops/R-3.4.2-200902111700/eclipse-SDK-$pkgver-linux-gtk$_arch.tar.gz
            eclipse.sh
            eclipse.desktop
	    eclipse.ini.patch)

build() {
  cd $startdir/src/eclipse || return 1

  # patch to increase default memory limits
  patch -p0 < ../eclipse.ini.patch || return 1

  # install eclipse
  mkdir -p $startdir/pkg/usr/share || return 1
  mv $startdir/src/eclipse $startdir/pkg/usr/share || return 1

  # install misc
  mkdir -p $startdir/pkg/etc/profile.d $startdir/pkg/usr/share/applications \
    $startdir/pkg/usr/share/icons/hicolor/{16x16,32x32,48x48}/apps \
  	|| return 1
  install -m755 $startdir/src/eclipse.sh \
  	$startdir/pkg/etc/profile.d/eclipse.sh || return 1
  install -m644 $startdir/src/eclipse.desktop \
  	$startdir/pkg/usr/share/applications/eclipse.desktop || return 1
  ln -s /usr/share/eclipse/plugins/org.eclipse.sdk_3.4.2.v200902111700/eclipse.png \
    $startdir/pkg/usr/share/icons/hicolor/16x16/apps/eclipse.png || return 1
  ln -s /usr/share/eclipse/plugins/org.eclipse.sdk_3.4.2.v200902111700/eclipse32.png \
    $startdir/pkg/usr/share/icons/hicolor/32x32/apps/eclipse.png || return 1
  ln -s /usr/share/eclipse/plugins/org.eclipse.sdk_3.4.2.v200902111700/eclipse48.png \
    $startdir/pkg/usr/share/icons/hicolor/48x48/apps/eclipse.png || return 1
}