# $Id: PKGBUILD 13728 2008-09-28 08:27:12Z tpowa $
# Maintainer: damir <damir@archlinux.org>

pkgname=amarok-base
_origname=amarok
replaces=("${_origname}" 'amarok-base-mysqlfree')
pkgver=1.4.10
pkgrel=1
pkgdesc="amaroK - a media player for KDE"
arch=("i686" "x86_64")
url="http://amarok.kde.org"
license=('GPL')
depends=('amarok-engine-xine=1.4.10' 'qt3' 'libmp4v2' 'libmysqlclient>=5.0.45' 'postgresql-libs>=8.2.4' 'ruby' 'tunepimp>=0.5.3')
makedepends=('pkgconfig' 'kdelibs3' 'libgpod>=0.6.0' 'libifp>=1.0.0.2' 'libmtp>=0.2.6.1' 'libnjb>=2.2.5' 'libvisual>=0.4.0' 'xine-lib>=1.1.8' 'sdl>=1.2.12')
# advanced scripting depends on python
install=amarok.install
#source=(http://mark.kollide.net/amarok-${pkgver}.tar.bz2
source=("ftp://ftp.solnet.ch/mirror/KDE/stable/amarok/${pkgver}/src/${_origname}-${pkgver}.tar.bz2"
	"amarok_addaspodcast.desktop" "wikipedia.patch")
options=(!makeflags)

build() {
  patch -Np0 -i $srcdir/wikipedia.patch || return 1

  cd ${startdir}/src/${_origname}-${pkgver}
  . /etc/profile.d/qt3.sh
  . /etc/profile.d/kde3.sh
   
  # prepare build
  ./configure --prefix=/opt/kde \
  	--with-gnu-ld \
	--enable-mysql \
	--enable-postgresql \
	--with-mp4v2 \
	--with-ifp \
	--with-libnjb \
	--with-libmtp \
	--with-libgpod \
	--without-arts \
	--without-gstreamer \
	--with-xine \
	--without-nmm \
	--without-mas \
	--with-libvisual \
	--disable-debug \
	--enable-debug=no \
	--without-xmms || return 1

  # build
  sed -i -e 's/konquisidebar//g' amarok/src/Makefile
  make || return 1
  make DESTDIR=${startdir}/pkg install || return 1

  # remove xine engine from pkg... separate pkg
  rm ${startdir}/pkg/opt/kde/lib/kde3/libamarok_xine-engine.{la,so}
  rm ${startdir}/pkg/opt/kde/share/config.kcfg/xinecfg.kcfg
  rm ${startdir}/pkg/opt/kde/share/services/amarok_xine-engine.desktop

  mkdir -p ${startdir}/pkg/opt/kde/share/apps/konqueror/servicemenus/
  install -m644 ${startdir}/src/amarok_addaspodcast.desktop ${startdir}/pkg/opt/kde/share/apps/konqueror/servicemenus/
}
md5sums=('3bdbf26181bf5e5925f48968caba7ac2'
         '7736a7e3e22b15818180df3cee7e4a79'
         'a93eb0dad2078afa045a69f38256b369')