pkgname=apache-ant
pkgver=1.7.1
pkgrel=2
pkgdesc="A java-based build tool."
arch=('i686' 'x86_64')
license=('APACHE')
url="http://ant.apache.org/"
depends=('java-runtime')
source=(http://archive.apache.org/dist/ant/binaries/${pkgname}-${pkgver}-bin.tar.bz2
        ${pkgname}.sh)
md5sums=('9330447f3763b87570dd1118c49a8efd'
         'c400a0937fa25d5a4c995ed220dd72b3')

build() {
  # install profile.d script
  install -dm755 ${pkgdir}/etc/profile.d || return 1
  install -m755 ${srcdir}/${pkgname}.sh ${pkgdir}/etc/profile.d/ || return 1

  # Get the ANT_HOME env var
  source ${srcdir}/${pkgname}.sh || return 1

  cd ${srcdir}/${pkgname}-${pkgver}
  install -dm755 ${pkgdir}/${ANT_HOME}/{bin,lib} || return 1

  install -m644 ./lib/*.jar ${pkgdir}/${ANT_HOME}/lib || return 1
  cp -Rp ./etc ${pkgdir}/${ANT_HOME} || return 1

  # Do not copy Windows .bat/.cmd files
  find ./bin -type f -a ! -name \*.bat -a ! -name \*.cmd \
    -exec install -m755 {} ${pkgdir}/${ANT_HOME}/bin \; || return 1

  # The license says the NOTICE file should be redistributed for derivative
  # works, so lets supply it.
  install -dm755 ${pkgdir}/usr/share/licenses/${pkgname} || return 1
  install -m644 LICENSE NOTICE ${pkgdir}/usr/share/licenses/${pkgname} || return 1
}