# $Id: PKGBUILD 356 2008-04-18 22:56:27Z aaron $
# Maintainer: Jeff 'codemac' Mickey <jeff@archlinux.org>
# Maintainer: aurelien <aurelien@archlinux.org>
# Contributor: Jochem Kossen <j.kossen@home.nl>
pkgname=zsh
pkgver=4.3.6
pkgrel=1
pkgdesc="A very advanced and programmable command interpreter (shell) for UNIX"
arch=('i686' 'x86_64')
url="http://www.zsh.org/"
license=('custom')
depends=('ncurses')
options=('!zipman')
install="zsh.install"
source=(ftp://ftp.zsh.org/pub/$pkgname-$pkgver.tar.bz2)
md5sums=('16f399af1081ad3c303a794c9c7dc47e')

build() {
  cd "$srcdir/$pkgname-$pkgver"

  ./configure --prefix=/usr --bindir=/bin \
  --enable-zsh-mem \
  --enable-zsh-secure-free \
  --enable-etcdir=/etc/zsh \
  --enable-zshenv=/etc/zsh/zshenv \
  --enable-zshrc=/etc/zsh/zshrc \
  --enable-zprofile=/etc/profile \
  --enable-zlogin=/etc/zsh/zlogin \
  --enable-zlogout=/etc/zsh/zlogout \
  --enable-function-subdirs \
  --enable-maildir-support \
  --enable-multibyte \
  --with-term-lib="ncursesw" \
  --with-tcsetpgrp

  make || return 1
  make DESTDIR="$pkgdir/" install

  install -D -m644 LICENCE $startdir/pkg/usr/share/licenses/$pkgname/LICENSE
}

# vim:set ts=2 sw=2 et: