# Original Contributor: Douglas Soares de Andrade <dsandrade@gmail.com>
# Updated by: Byron Clark <byron@theclarkfamily.name>

pkgname=twisted
_realname=Twisted
pkgver=8.0.1
pkgrel=2
pkgdesc="Asynchronous networking framework written in Python"
arch=(i686 x86_64)
url="http://twistedmatrix.com"
license=('custom:MIT')
depends=('python' 'pycrypto' 'zope-interface')
optdepends=('pygtk: for running the manhole GUI')
provides=(twisted)
conflicts=(twisted)
replaces=(twisted)
source=(http://tmrc.mit.edu/mirror/twisted/$_realname/${pkgver%.*}/$_realname-$pkgver.tar.bz2)
md5sums=('1ba5bb530356a867cfee35e65e58a43c')

build() {
  cd $startdir/src/$_realname-$pkgver
  python setup.py install --prefix=/usr --root=$startdir/pkg || return 1

  # manpages not installed by setup.py
  install -d -m 0755 $startdir/pkg/usr/share/man/man1
  for docdir in doc/*/man; do
    for manpage in $docdir/*.1; do
      install -m 0644 $manpage $startdir/pkg/usr/share/man/man1/
    done
  done

  install -D -m 0644 LICENSE $startdir/pkg/usr/share/licenses/$pkgname/LICENSE
}
# vim:set ts=2 sw=2 et: