# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=gnome-power-manager
pkgver=2.20.1
pkgrel=1
pkgdesc="Session daemon that makes it easy to manage your laptop or desktop system."
arch=(i686 x86_64)
url="http://www.gnome.org/projects/gnome-power-manager/"
license=('GPL')
depends=('libnotify>=0.4.4' 'gnome-panel>=2.20.0' 'gstreamer0.10')
makedepends=('gettext' 'perlxml' 'pkgconfig' 'gnome-doc-utils>=0.12.0')
options=(!emptydirs)
install=gnome-power-manager.install
groups=(gnome-extra)
source=(http://ftp.gnome.org/pub/GNOME/sources/gnome-power-manager/2.20/${pkgname}-${pkgver}.tar.bz2
        gnome-power-manager-2.17.92-tray-kde.patch
        brightness.patch)
md5sums=('6bf1bd7fba0ab8362d6ae1919dd7a732'
         'ae15a1b3b6bb45b999175d2414710115'
         'ba9bd692f236ca0fcda958301fb1a5d0')

build() {
  cd ${startdir}/src/${pkgname}-${pkgver}
  patch -Np0 -i ${startdir}/src/gnome-power-manager-2.17.92-tray-kde.patch || return 1
  patch -Np0 -i ${startdir}/src/brightness.patch || return 1

  ./configure --prefix=/usr --sysconfdir=/etc \
              --localstatedir=/var \
	      --with-dpms-ext \
              --disable-scrollkeeper \
              --with-dbus-sys=/etc/dbus-1/system.d \
              --with-dbus-services=/usr/share/dbus-1/services \
              --enable-applets
  make || return 1
  make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR=${startdir}/pkg install

  mkdir -p ${startdir}/pkg/usr/share/gconf/schemas
  gconf-merge-schema ${startdir}/pkg/usr/share/gconf/schemas/${pkgname}.schemas ${startdir}/pkg/etc/gconf/schemas/*.schemas
  rm -f ${startdir}/pkg/etc/gconf/schemas/*.schemas
}