# Maintainer: Stefan Husmann <stefan-husmann@t-online.de>
# Contributor: max_meyer <dev@fedux.org>

pkgname=svg2tikz-git
_gitname="svg2tikz"
pkgver=2.1.0+78.r442.20231102.aab48a4
pkgrel=2
pkgdesc="set of tools for converting SVG graphics to TikZ/PGF code"
arch=('any')
url="https://github.com/kjellmf/svg2tikz"
license=('GPL2')
depends=('python-lxml' 'python-inkex')
makedepends=('git' 'python-build' 'python-installer' 'python-wheel')
provides=(
  "inkscape-tikz=${pkgver}"
  "svg2tikz=${pkgver}"
)
conflicts=(
  'inkscape-tikz'
  'svg2tikz'
)
replaces=(
  'inkscape-tikz-hg'
)
optdepends=(
  'inkscape: for using the inksape extension files'
)
source=(
  "${_gitname}::git+https://github.com/kjellmf/svg2tikz"
)
sha256sums=(
  'SKIP'
)

prepare() {
  cd "$srcdir"/"$_gitname"
  [[ -d build ]] || rm -rf build

  git log > git.log
}

pkgver() {
  cd "$srcdir"/"$_gitname"

  _ver="$(git describe --tags | sed 's|^[vV]||' | sed 's|-[^-]*$||' | tr '-' '+')"
  _rev="$(git rev-list --count HEAD)"
  _date="$(git log -1 --date=format:"%Y%m%d" --format="%ad")"
  _hash="$(git rev-parse --short HEAD)"

  if [ -z "${_ver}" ]; then
    error "Version could not be determined."
    return 1
  else
    printf '%s' "${_ver}.r${_rev}.${_date}.${_hash}"
  fi
}

build() {
  cd "$srcdir/$_gitname"

  python -m build --wheel --no-isolation
}

package() {
  cd "$srcdir/$_gitname"

  python -m installer --destdir="${pkgdir}" dist/*.whl

  _inkscape_ext="$pkgdir/usr/share/inkscape/extensions"
  install -dvm755 "$_inkscape_ext"

  install -Dvm644 svg2tikz/*.inx -t "$_inkscape_ext"
  install -Dvm755 svg2tikz/tikz_export.py -t "$_inkscape_ext"

  for _docfile in git.log CHANGELOG.md README.md; do
    install -Dvm644 "${_docfile}" -t "${pkgdir}/usr/share/doc/svg2tikz/"
  done
}